Συνάρτηση IF excel

Περίληψη

Η συνάρτηση IF είναι μία λογική συνάρτηση η οποία αναλόγως μίας λογικής συνθήκης, καθορίζει το περιεχόμενο του κελιού. Η συνάρτηση IF ελέγχει μία λογική συνθήκη και επιστρέφει μία τιμή για την τιμή TRUE και μία τιμή για την τιμή FALSE. Για παράδειγμα αν θέλουμε να εμφανίσουμε την λέξη "ΟΚ" αν η βαθμολογία είναι μεγαλύτερη από 50 και "Επανέλεγχος" σε διαφορετική περίπτωση:

=IF(A1>50;"ΟΚ";"Επανέλεγχος"). Μπορούν να ελεγχθούν περισσότερες από μία λογικές εκφράσεις στην IF με την βοήθεια των συναρτήσεων AND, OR, XOR.

Σκοπός

Να ελέγξει μία συνθήκη. Επιστρέφει μία εκ των δύο τιμών που έχουμε ορίσει στις περιπτώσεις TRUE και FALSE

Syntax

=IF (logical_test, [value_if_true], [value_if_false])

Ορίσματα - Παραμέτρους

logical_test - Μία τιμή ή λογική έκφραση η οποία όταν αξιολογείται επιστρέφει TRUE ή FALSE.
value_if_true - [Προαιρετικό] Η τιμή που θα επιστραφεί όταν το logical_test επιστρέψει TRUE.
value_if_false - [Προαιρετικό] Η τιμή που θα επιστραφεί όταν το logical_test επιστρέψει FALSE.

Οδηγίες χρήσης 

Η συνάρτηση IF χρησιμοποιείται για να ελέγξει μία λογική συνθήκη και προσαρμόζει το αποτέλεσμα αναλόγως με το αν η συνθήκη ισχύει ή όχι. Δηλαδή επιστρέφει TRUE ή FALSE. Η πρώτη παράμετρος, λογικός_έλεγχος (logical_test), είναι μία έκφραση η οποία επιστρέφει λογικό TRUE ή FALSE. Και οι δύο τιμές στις παραμέτρους τιμή_αν_true (value_if_true) και τιμή_αν_false (value_if_false) είναι προαιρετικές, αλλά τουλάχιστον μία εκ των δύο θα πρέπει να δοθεί. Το αποτέλεσμα της συνάρτησης IF μπορεί να είναι μία αναφορά σε κελί ή ακόμα και κάποιος άλλος τύπος ή συνάρτηση.

Στο παρακάτω παράδειγμα, θέλουμε να αποφασίσουμε αν θα έχουμε έκπτωση ή όχι βασιζόμενοι στο τελικό ποσό αγορών. Αν οι αγορές είναι μεγαλύτερες των 100€ τότε θέλουμε το μήνυμα "Μειωμένη τιμή", διαφορετικά "Κανονική τιμή". Στο κελί D5 γράφουμε τον παρακάτω τύπο:

=IF(C6>100;"Μειωμένη τιμή";"Κανονική τιμή")

Αν η τιμή στο κελί C6 είναι μεγαλύτερη του 100, εμφάνισε την φράση "Μειωμένη τιμή" διαφορετικά εμφάνισε "Κανονική τιμή".

Ο παραπάνω τύπος μπορεί να γραφεί και με ανάστροφη λογική κρατώντας το ίδιο αποτέλεσμα. Δείτε το επόμενο παράδειγμα με ανεστραμμένη λογική:

=IF(C6<=100,"Κανονική τιμή";"Μειωμένη τιμή")

Αν η τιμή στο κελί C6 είναι μικρότερη ή ίση με το 100 τότε επέστρεψε "Κανονική τιμή", διαφορετικά "Μειωμένη τιμή".

Και οι δύο συναρτήσεις θα δώσουν σωστά αποτελέσματα, οπότε μπορείτε να τις χρησιμοποιήσετε και τις δύο χωρίς πρόβλημα.

Επιστροφή τύπου ως αποτέλεσμα της IF

Η συνάρτηση IF μπορεί να επιστρέψει έναν άλλο τύπο ως αποτέλεσμα. Για παράδειγμα, ο παρακάτω τύπος θα επιστρέψει την τιμή του κελιού A1* 5% όταν η τιμή του κελιού A1 είναι μικρότερη του 50, και σε διαφορετική περίπτωση θα επιστρέψει την τιμή του κελιού A1*7%:

=IF(A1<50;A1*5%;A1*7%)

Εμφωλευμένες IF (IF μέσα σε IF)

Η συνάρτηση IF μπορεί να εμφωλευθεί. Η λέξη εμφώλευση αναφέρεται στην περίπτωση όπου μία συνάρτηση IF βρίσκεται εντός μίας άλλης συνάρτησης IF με σκοπό να ελέγξουμε περισσότερες συνθήκες και να επιστρέψουμε περισσότερα αποτελέσματα. Χρειάζεται προσοχή τόσο στην σύνταξη όσο και την τήρηση της λογικής ώστε κάθε φορά να προκύπτει ένα μόνο αποτέλεσμα.

Στο παρακάτω παράδειγμα, υπάρχει μία κλιμάκωση βαθμολογίας ώστε να μας επιστρέφει έναν συγκεκριμένο χαρακτηρισμό βαθμολογίας:

=IF(C6<70,"F",IF(C6<75,"D",IF(C6<85,"C",IF(C6<95,"B","A"))))

Μέχρι και 64 IF μέσα σε IF μπορούν να εμφωλευθούν. Ωστόσο στην περίπτωση όπου έχουμε τόσο περίπλοκες περιπτώσεις ελέγχου, καλό είναι να χρησιμοποιούμε την VLOOKUP, HLOOKUP ή XLOOKUP, λόγω του ότι μπορούν πιο εύκολα να διαχειριστούν συνθήκες και να επιστρέψουν αποτελέσματα χωρίς να υπάρχει πιθανότητα λάθους.

Λογικοί τελεστές

Όταν δημιουργείτε με την συνάρτηση IF μπορείτε να χρησιμοποιείτε στους ελέγχους σας τους παρακάτω λογικούς τελεστές:

Η συνάρτηση IF δεν υποστηρίζει χαρακτήρες μπαλαντέρ, ωστόσο μπορείτε να συνδυάσετε με την συνάρτηση COUNTIF για μία υποτυπώδη προσομοίωση χρήσης χαρακτήρων μπαλαντέρ.

Συνάρτηση IF σε συνδυασμό με AND, OR, NOT

Η συνάρτηση IF μπορεί να συνδυαστεί με τις λογικές συναρτήσεις AND και OR. Για παράδειγμα,  εάν θέλουμε να επιστραφεί η τιμή "OK" όταν η τιμή του κελιού A1 είναι μεταξύ 7 και 10, μπορούμε να γράψουμε τον παρακάτω τύπο:

=IF(AND(A1>7;A1<10);"OK";"")

Εξήγηση: Αν το κελί A1 είναι μεγαλύτερο από 7 και μικρότερο από 10, επέστρεψε "OK". Διαφορετικά, μην επιστρέφεις τίποτα ("").

Για να επιστρέψετε το αποτέλεσμα του τύπου B1+10 όταν η τιμή του κελιού A1 είναι "Κόκκινο" ή "Μπλε" μπορείτε να χρησιμοποιήσετε την συνάρτηση OR ως εξής:

=IF(OR(A1="Κόκκινο";A1="Μπλε");B1+10;B1)

Εξήγηση: Αν το κελί A1 έχει την τιμή "Κόκκινο ή "Μπλε", επέστρεψε την τιμή του B1+10, διαφορετικά επέστρεψε την τιμή του κελιού B1.

=IF(NOT(A1="Κόκκινο");B1+10;B1)

Εξήγηση: Αν η τιμή του κελιού A1 ΔΕΝ είναι "Κόκκινο" τότε επέστρεψε την τιμή του B1+10, διαφορετικά επέστρεψε την τιμή του κελιού Β1.

Γενικές σημειώσεις

• Για να μετρήσουμε πλήθος υπό συνθήκες, χρησιμοποιούμε την συνάρτηση COUNTIF ή την συνάρτηση COUNTIFS.
• Για να αθροίσουμε υπό συνθήκες, χρησιμοποιούμε την συνάρτηση SUMIF ή την συνάρτηση SUMIFS.
• Αν οποιοδήποτε όρισμα της IF είναι ένας πίνακας τιμών, η συνάρτηση IF θα αξιολογήσει το κάθε στοιχείο του πίνακα ξεχωριστά.